ПриложениеКлиент.Результат (ServiceClient.Resalt) Свойство

Использование

Чтение и запись.

Значение

Тип: Произвольный.

Возвращает или задает результат выполнения метода приложения (скрипта) в контексте клиента.

Примечание

Тип значения свойства может быть Строка, Число, Булево, Дата, ДвоичныеДанные.

Важно: Только через это свойство можно получить результат выполнения метода.

Важно: Присвоить значение этому свойству внутри одного метода допускается только один раз.

Пример

ПриложениеКлиент1.Результат = "ПроцедураНаКлиенте. Сумма параметров = " + Сумма + " (время = " + ТекущаяУниверсальнаяДатаВМиллисекундах() + ")";
Полный пример кода 

Копировать     Выделить всё


//== Файл Сервер.os == начало
Перем КС, ПриложениеСервис1;

Процедура ПриложениеСервис_ПриПодключенииКлиента() Экспорт
	ПриложениеКлиентАрг = КС.ПриложениеКлиентАрг();
	Клиент = ПриложениеКлиентАрг.Клиент;
	Сообщить("Подключен новый клиент. Идентификатор клиента = " + Клиент.ИдентификаторКлиента);
	Сообщить("Количество подключенных к серверу клиентов = " + ПриложениеСервис1.Клиенты.Количество());
	
	Клиенты = ПриложениеСервис1.Клиенты;
	Для А = 0 По Клиенты.ВГраница() Цикл
		Сообщить("ГуидКлиента = " + Клиенты[А].ГуидКлиента);
	КонецЦикла;
	
	МассивПараметров = Новый Массив();
	МассивПараметров.Добавить(125.35);
	МассивПараметров.Добавить(25);
	МассивПараметров.Добавить(75);
	
	Сообщить("Результат = " + ПриложениеСервис1.ВыполнитьНаКлиенте(Клиенты[0].ГуидКлиента, "ПроцедураНаКлиенте", МассивПараметров));
	// Сообщить("Результат = " + ПриложениеСервис1.ВыполнитьНаКлиенте(Клиенты[0].ГуидКлиента, "ПроцедураНаКлиенте"));
	Сообщить("========================================");
КонецПроцедуры

ПодключитьВнешнююКомпоненту("C:\444\111\OneScriptClientServer\OneScriptClientServer\bin\Debug\OneScriptClientServer.dll");
КС = Новый КлиентСерверДляОдноСкрипта();
ПриложениеСервис1 = КС.ПриложениеСервис(10085, ЭтотОбъект);
ПриложениеСервис1.ПриПодключенииКлиента = КС.Действие(ЭтотОбъект, "ПриложениеСервис_ПриПодключенииКлиента");

ПриложениеСервис1.Начать();
Сообщить("ПриложениеСервис запущен");

Пока КС.Продолжать Цикл
	КС.ПолучитьСобытие().Выполнить();
КонецЦикла;
//== Файл Сервер.os == конец

//== Файл Клиент.os == начало
Перем КС, ПриложениеКлиент1;

Процедура ПроцедураНаКлиенте() Экспорт
	ВыполнитьНаКлиентеАрг = КС.АргументыСобытия;
	Сообщить("ИмяМетода = " + ВыполнитьНаКлиентеАрг.ИмяМетода);
	МассивПараметров = ВыполнитьНаКлиентеАрг.МассивПараметров;
	Сумма = 0;
	Для А = 0 По МассивПараметров.ВГраница() Цикл
		Параметр = МассивПараметров.Получить(А);
		Сообщить("Параметр " + А + " = " + Параметр);
		// В нашем случае мы знаем, что тип значения параметров - Число.
		Сумма = Сумма + Параметр;
	КонецЦикла;
	ПриложениеКлиент1.Результат = "ПроцедураНаКлиенте. Сумма параметров = " + Сумма + " (время = " + ТекущаяУниверсальнаяДатаВМиллисекундах() + ")";
	Сообщить("Результат = " + ПриложениеКлиент1.Результат);
	Сообщить("================================");
КонецПроцедуры

ПодключитьВнешнююКомпоненту("C:\444\111\OneScriptClientServer\OneScriptClientServer\bin\Debug\OneScriptClientServer.dll");
КС = Новый КлиентСерверДляОдноСкрипта();
ПриложениеКлиент1 = КС.ПриложениеКлиент(КС.TCPКонечнаяТочка("127.0.0.1", 10085), ЭтотОбъект);

ПриложениеКлиент1.Подключить();
Приостановить(1000);

Пока КС.Продолжать Цикл
	КС.ПолучитьСобытие().Выполнить();
КонецЦикла;
//== Файл Клиент.os == конец

Смотрите также

ПриложениеКлиент (ServiceClient) Класс | Библиотека OneScriptClientServer