ПриложениеКлиент.Метка (ServiceClient.Tag) Свойство

Использование

Чтение и запись.

Значение

Тип: Структура.

Возвращает или задает объект, содержащий дополнительные данные для клиента, которые возможно передать по сети.

Примечание

Тип значения дополнительных данных может быть Строка, Число, Булево, Дата, ДвоичныеДанные, Неопределено.

Ссылочные типы данных приводятся к типу Строка.

Пример

ПриложениеКлиент1.Метка = НашаСтруктура;
НашаСтруктура2 = ПриложениеКлиент1.Метка;
Полный пример кода 

Копировать     Выделить всё


//== Файл Сервер.os == начало
Перем КС;

Процедура ПриложениеСервис_ПриПодключенииКлиента() Экспорт
	ПриложениеКлиентАрг = КС.АргументыСобытия;
	Сообщить("Клиент подключен! Гуид клиента = " + ПриложениеКлиентАрг.Клиент.ГуидКлиента);
	Сообщить("========================================");
КонецПроцедуры

ПодключитьВнешнююКомпоненту("C:\444\111\OneScriptClientServer\OneScriptClientServer\bin\Debug\OneScriptClientServer.dll");
КС = Новый КлиентСерверДляОдноСкрипта();
ПриложениеСервис1 = КС.ПриложениеСервис(10085, ЭтотОбъект);
ПриложениеСервис1.ПриПодключенииКлиента = КС.Действие(ЭтотОбъект, "ПриложениеСервис_ПриПодключенииКлиента");

ПриложениеСервис1.Начать();
Сообщить("ПриложениеСервис запущен");

Пока КС.Продолжать Цикл
	КС.ПолучитьСобытие().Выполнить();
КонецЦикла;
//== Файл Сервер.os == конец

//== Файл Клиент.os == начало
ПодключитьВнешнююКомпоненту("C:\444\111\OneScriptClientServer\OneScriptClientServer\bin\Debug\OneScriptClientServer.dll");
КС = Новый КлиентСерверДляОдноСкрипта();
ПриложениеКлиент1 = КС.ПриложениеКлиент(КС.TCPКонечнаяТочка("127.0.0.1", 10085), ЭтотОбъект);
ПриложениеКлиент1.ИмяКлиента = "Клиент1";

НашаСтруктура = Новый Структура("Поле1, Поле2","ЧтоТоТам1", "ЧтоТоТам2");
НашаСтруктура.Вставить("Булево", Истина);
НашаСтруктура.Вставить("Число", 156.35);
НашаСтруктура.Вставить("Дата", Дата(1984,03,26,06,24,21));
НашаСтруктура.Вставить("Неопределено", Неопределено);
НашаСтруктура.Вставить("ПриложениеКлиент1", ПриложениеКлиент1);
// ДД = Новый ДвоичныеДанные("C:\444\Pic\Games4.JPG");
// НашаСтруктура.Вставить("ДД", ДД);

ПриложениеКлиент1.Метка = НашаСтруктура;
НашаСтруктура2 = ПриложениеКлиент1.Метка;
Для Каждого Эл Из НашаСтруктура2 Цикл
	Сообщить("Ключ = " + Эл.Ключ + " Значение = " + Эл.Значение);
КонецЦикла;
Сообщить("=====================");

ПриложениеКлиент2 = КС.ПриложениеКлиент(КС.TCPКонечнаяТочка("127.0.0.1", 10085), ЭтотОбъект);
ПриложениеКлиент2.ИмяКлиента = "Клиент2";

ПриложениеКлиент1.Подключить();
ПриложениеКлиент2.Подключить();
Приостановить(1000);

Массив = ПриложениеКлиент1.ПолучитьИнформациюКлиентов();
Для А = 0 По Массив.ВГраница() Цикл
	ИнформацияКлиента = Массив.Получить(А);
	Сообщить("ГуидКлиента = " + ИнформацияКлиента.ГуидКлиента);
	Сообщить("ИмяКлиента = " + ИнформацияКлиента.ИмяКлиента);
	Для Каждого Эл Из ИнформацияКлиента.Метка Цикл
		Сообщить("Ключ = " + Эл.Ключ + " Значение = " + Эл.Значение);
	КонецЦикла;
	Сообщить("=====================");
КонецЦикла;

Пока КС.Продолжать Цикл
	КС.ПолучитьСобытие().Выполнить();
КонецЦикла;
//== Файл Клиент.os == конец

Смотрите также

ПриложениеКлиент (ServiceClient) Класс | Библиотека OneScriptClientServer