МногопоточныйTCPСерверДляОдноСкрипта.ФоновыйTCPКлиентSSL (OneScriptMultithreadedTCPServer.BackgroundTCPClientSSL) Метод

Копировать

Перем МС;

Процедура ВывестиСообщение(Данные)
	Попытка	
		// В случае передачи в потоке перед самим сообщением размера сообщения используем этот вариант.
		РазмерДанных = Данные.ПрочитатьЦелое32(0);
		ДанныеСообщения = Данные.Прочитать(4, РазмерДанных);
		ДД = ПолучитьДвоичныеДанныеИзБуфераДвоичныхДанных(ДанныеСообщения);
		ОтдельноеСообщение = ПолучитьСтрокуИзДвоичныхДанных(ДД, КодировкаТекста.UTF8);
		Сообщить("1 Получено сообщение: " + " (" + РазмерДанных + " байт):" + Символы.ПС + ОтдельноеСообщение);
		Если (Данные.Размер - 4 - РазмерДанных) > 0 Тогда
			ОстатокДанных = Данные.Прочитать(4 + РазмерДанных, Данные.Размер - 4 - РазмерДанных);
			// Продолжаем делить данные на отдельные сообщения.
			ВывестиСообщение(ОстатокДанных);
		КонецЕсли;
	Исключение
		// В случае передачи в потоке никак не разделенных байтов используем этот вариант.
		ДанныеСообщения = Данные.Прочитать(0, Данные.Размер);

		ОтдельноеСообщение = ПолучитьСтрокуИзБуфераДвоичныхДанных(ДанныеСообщения, КодировкаТекста.UTF8);
		Сообщить("2 Получено сообщение: " + " (" + Данные.Размер + " байт):" + Символы.ПС + ОтдельноеСообщение);
	КонецПопытки;
	// Можно предусмотреть другие способы разделения потока байтов на отдельные сообщения, например посылка символа перевода строки.
КонецПроцедуры

Процедура КлиентПолучилДанные() Экспорт
	Сообщить("КлиентПолучилДанные");
	АргументыСобытия = МС.АргументыСобытия;
	Данные = АргументыСобытия.Данные;
	// Данные, полученные клиентом, доступны нам как тип БуферДвоичныхДанных (BinaryDataBuffer).
	// Если с клиентом будет взаимодействовать сервер, который формирует сообщения по оговоренным заранее правилам, 
	// появляется возможность делить данные на отдельные сообщения и кроме того знать тип данных отдельного сообщения.
	// Как частный случай можно на стороне сервера отправлять в сетевой поток сначала размер сообщения (четыре байта) 
	// а затем само сообщение.
	ВывестиСообщение(Данные);
	Сообщить("========================");
КонецПроцедуры

ПодключитьВнешнююКомпоненту("C:\444\111\MultithreadedTCPServer\MultithreadedTCPServer\bin\Debug\MultithreadedTCPServer.dll");
МС = Новый МногопоточныйTCPСерверДляОдноСкрипта();

ТекПуть = Новый Файл(ТекущийСценарий().Источник).Путь;
Клиент = МС.ФоновыйTCPКлиентSSL("127.0.0.1", 8080, ОбъединитьПути(ТекПуть, "certificate.crt"));
Клиент.КлиентПолучилДанные = МС.Действие(ЭтотОбъект, "КлиентПолучилДанные");
Приостановить(1000);

Сообщить("Подключен");
Сообщить("Печатайте и нажмите ENTER");

// Фоновый TCP клиент не блокирует выполнение сценария.
// Не будем закрывать подключение и остановимся в цикле ввода сообщений.
Результат = Неопределено;
Пока ВвестиСтроку(Результат, , , ) Цикл
	Клиент.Отправить(ПолучитьБуферДвоичныхДанныхИзСтроки(Результат));
КонецЦикла;