ProgressBarFormat Property

Использование

Чтение и запись.

Значение

Тип: ФорматИндикатора (ProgressBarFormat).

Возвращает или задает формат, который используется в индикатор для визуального отображения.

Примечание

Применяется совместно со свойством Индикатор.СтильИндикатора (ProgressBar.ProgressBarStyle), установленным в значения Блоки (Blocks) или Полоса (Continuous).

Пример

Индикатор1.ФорматИндикатора = ТФ.ФорматИндикатора.КадрПроценты;

Полный пример кода



Перем ТФ, Окно1, Индикатор1, Счетчик1, Таймер1;

Процедура ПриОткрытии() Экспорт
	ТФ.ОтправитьКлавиши("С", Ложь, Ложь, Ложь);
	ФорматИндикатора = Индикатор1.ФорматИндикатора;
	ТФ.Уведомление().Показать("ФорматИндикатора = " + ФорматИндикатора, 3000);
КонецПроцедуры

Процедура Кнопка1_Нажатие() Экспорт
	Таймер1.Остановить();
	Счетчик1 = 0;
	Индикатор1.Значение = 0;
	Таймер1.Начать();
КонецПроцедуры

Процедура Кнопка2_Нажатие() Экспорт
	Таймер1.Остановить();
КонецПроцедуры

Процедура Таймер1_ПриСрабатыванииТаймера() Экспорт
	Счетчик1 = Счетчик1 + 0.01;
	Индикатор1.Значение = Счетчик1;
	Окно1.Текст = "Счетчик1 = " + Счетчик1 + " " + ТекущаяУниверсальнаяДатаВМиллисекундах();
	Если Счетчик1 >= 1 Тогда
		Индикатор1.Значение = 0;
		Таймер1.Остановить();
	КонецЕсли;
КонецПроцедуры

ПодключитьВнешнююКомпоненту("C:\444\111\OneScriptTerminalGui\OneScriptTerminalGui\bin\Debug\OneScriptTerminalGui.dll");
ТФ = Новый ТерминалФормыДляОдноСкрипта();

Окно1 = ТФ.Окно();
Окно1.Заголовок = "Окно1";
Окно1.Заполнить();
ТФ.Верхний.Добавить(Окно1);

Индикатор1 = Окно1.Добавить(ТФ.Индикатор(, , 60));
Индикатор1.Центр();
Индикатор1.Значение = 0;
Индикатор1.ЦветоваяСхема = ТФ.Цвета.Основа;
Индикатор1.СтильИндикатора = ТФ.СтильИндикатора.Блоки;

Кнопка1 = Окно1.Добавить(ТФ.Кнопка("Старт", , , 10, 1));
Кнопка1.Центр();
Кнопка1.Выше(Индикатор1, 2);
Кнопка1.Граница = ТФ.Граница(ТФ.СтильГраницы.Закругленная);
Кнопка1.Нажатие = ТФ.Действие(ЭтотОбъект, "Кнопка1_Нажатие");

Кнопка2 = Окно1.Добавить(ТФ.Кнопка("С_топ", , , 10, 1));
Кнопка2.Центр();
Кнопка2.Ниже(Индикатор1, 2);
Кнопка2.Граница = ТФ.Граница(ТФ.СтильГраницы.Закругленная);
Кнопка2.Нажатие = ТФ.Действие(ЭтотОбъект, "Кнопка2_Нажатие");

Счетчик1 = 0;

Таймер1 = ТФ.Таймер();
Таймер1.Интервал = 50;
Таймер1.ПриСрабатыванииТаймера = ТФ.Действие(ЭтотОбъект, "Таймер1_ПриСрабатыванииТаймера");

Индикатор1.ФорматИндикатора = ТФ.ФорматИндикатора.КадрПроценты;

ТФ.ПриОткрытии = ТФ.Действие(ЭтотОбъект, "ПриОткрытии");

ТФ.Запуск();

Тестовый код



Перем ТФ, Окно1, Индикатор1, Таймер1, ФорматИндикатора;

Процедура ПриОткрытии() Экспорт
	Индикатор = Индикатор1;
	Окно1.Текст = "Индикатор1 = " + Индикатор + "
	|Нажмите кнопку Старт";
	ТФ.ОтправитьКлавиши("С", Ложь, Ложь, Ложь);
	ФорматИндикатора = Индикатор1.ФорматИндикатора;
КонецПроцедуры

Процедура Кнопка1_Нажатие() Экспорт
	Таймер1.Остановить();
	Таймер1.Начать();
КонецПроцедуры

Процедура Кнопка2_Нажатие() Экспорт
	Таймер1.Остановить();
КонецПроцедуры

Процедура Таймер1_ПриСрабатыванииТаймера() Экспорт
	Индикатор1.Шаг();
КонецПроцедуры

ПодключитьВнешнююКомпоненту("C:\444\111\OneScriptTerminalGui\OneScriptTerminalGui\bin\Debug\OneScriptTerminalGui.dll");
ТФ = Новый ТерминалФормыДляОдноСкрипта();

Окно1 = ТФ.Верхний.Добавить(ТФ.Окно("Окно1"));
Окно1.Заголовок = "Окно1";
Окно1.Заполнить();

Индикатор1 = Окно1.Добавить(ТФ.Индикатор(, , 60));
Индикатор1.Центр();
Индикатор1.Значение = 0.4;
Индикатор1.ЦветоваяСхема = ТФ.Цвета.Основа;
Индикатор1.СтильИндикатора = ТФ.СтильИндикатора.БегущаяПолоса;

Кнопка1 = Окно1.Добавить(ТФ.Кнопка("Старт", , , 10, 1));
Кнопка1.Центр();
Кнопка1.Выше(Индикатор1, 2);
Кнопка1.Граница = ТФ.Граница(ТФ.СтильГраницы.Закругленная);
Кнопка1.Нажатие = ТФ.Действие(ЭтотОбъект, "Кнопка1_Нажатие");

Кнопка2 = Окно1.Добавить(ТФ.Кнопка("С_топ", , , 10, 1));
Кнопка2.Центр();
Кнопка2.Ниже(Индикатор1, 2);
Кнопка2.Граница = ТФ.Граница(ТФ.СтильГраницы.Закругленная);
Кнопка2.Нажатие = ТФ.Действие(ЭтотОбъект, "Кнопка2_Нажатие");

Таймер1 = ТФ.Таймер();
Таймер1.Интервал = 80;
Таймер1.ПриСрабатыванииТаймера = ТФ.Действие(ЭтотОбъект, "Таймер1_ПриСрабатыванииТаймера");

Индикатор1.ФорматИндикатора = ТФ.ФорматИндикатора.КадрПроценты;

ТФ.ПриОткрытии = ТФ.Действие(ЭтотОбъект, "ПриОткрытии");
ТФ.ЗапуститьИЗавершить();

Сообщить(?(
ТФ.ФорматИндикатора.Имя(ФорматИндикатора) = "КадрПроценты"
, "", "!!! ") + "Индикатор.ФорматИндикатора (ProgressBar.ProgressBarFormat) Свойство" + " " + ТекущаяДата() + Символы.ПС);

Смотрите также

Библиотека OneScriptTerminalGui